Защита ПК RFID-замком на реле: Arduino-проект

Компоненты и материалы

О проекте

Дополнительная защита ПК кроме пароля: RFID-метка включает питание (замыкает кнопку Power), другая метка — имитирует длительное нажатие (выключение).

База кода — классический RFID-замок. Сначала считываем UID карт через пример DumpInfo из библиотеки MFRC522, потом прописываем их в скетч.

Реле срабатывает на 500 мс (включение). Ключ-брелок держит реле 5 с (выключение, как долгое нажатие Power).

Код (RFID-Relay)

/* Использует библиотеку MFRC522: https://github.com/miguelbalboa/rfid */
#include <SPI.h>
#include <MFRC522.h>

#define RST_PIN 9
#define SS_PIN 10
MFRC522 mfrc522(SS_PIN, RST_PIN);

String read_rfid;
String ok_rfid_1 = "e199312d"; // основная карта — включение ПК
String ok_rfid_2 = "fbecb673"; // брелок — аварийное выключение
int relayPin = 7;

void setup() {
  Serial.begin(9600);
  while (!Serial);
  SPI.begin();
  mfrc522.PCD_Init();
  pinMode(relayPin, OUTPUT);
}

void dump_byte_array(byte *buffer, byte bufferSize) {
  read_rfid = "";
  for (byte i = 0; i < bufferSize; i++) {
    read_rfid += String(buffer[i], HEX);
  }
}

void pulseRelay(int ms) {
  digitalWrite(relayPin, HIGH);
  delay(ms);
  digitalWrite(relayPin, LOW);
}

void loop() {
  if (!mfrc522.PICC_IsNewCardPresent()) return;
  if (!mfrc522.PICC_ReadCardSerial()) return;

  dump_byte_array(mfrc522.uid.uidByte, mfrc522.uid.size);
  Serial.println(read_rfid);

  if (read_rfid == ok_rfid_1) {
    pulseRelay(500); // включение
  }
  if (read_rfid == ok_rfid_2) {
    pulseRelay(5000); // выключение (долгое нажатие)
  }
}

Библиотека

MFRC522: github.com/miguelbalboa/rfid

Схема подключения (Photoshop)